中财网高考搞笑口号霸气押韵:读入和写出数据文件并实现多载荷步瞬态动力学求解例子
来源：百度文库 编辑：中财网 时间：2024/04/29 13:07:19
一根半径为0.1m长度为10m的圆柱杆直立在地面上，下端完全固定，现在记录有0～10s之间每隔1s时候上部端点的水平作用力大小
，并按时间已经记录在数据文件ftop.dat中。计算圆柱杆的动态响应，提取顶点在激励方向上水平位移并存入数据文件utop.dat
中。
首先创建ftop.dat文件并存放在ansys的当前目录下，其包含的数据内容如下：（第一列数据占3个字符宽度，第二列数据占11个
字符宽度）
1 1600
2 7000
3 15000
4 5000
5 500
6 -2000
7 -800
8 1800
9 200
10 -3400
命令流：
*create,byb,mac
finish
/clear
*dim,ftop,,10,2
*vread,ftop(1,1),ftop,dat,,jik,2,10
(f3.0,f11.0)
!按指定格式输入数据
/prep7
et,1,beam189
sectype,1,beam,csolid,cir-sect,0
secoffset,cent
secdata,0.1
!定义梁189的截面号1
mp,ex,1,2e11
mp,nuxy,1,0.3
mp,dens,1,7800
!定义材料
/view,1,1,1,1
/ang,1
!调整图形为等视图显示
k,1
k,2,,,10
k,3,1
lstr,1,2
latt,1,,1,,3,,1
!给线分配单元属性：mat＝1，type＝1，方向kp＝3
esize,1,0
lmesh,1
/eshape,1
!打开单元截面形状显示开关
eplot
dk,1,all,0
save
finish
!执行瞬态分析的循环求解过程
/solu
antype,4
!选择瞬态分析类型
trnopt,full
!选择瞬态完全法
nlgeom,1
!打开几何打变形开关
outres,all,all
!求解输入所有子步的所有结果项到结果文件中
autots,0
!关闭自动调整载荷长功能
kbc,0
!采用渐变载荷加载方式
*do,i,1,10
!执行10次循环加载
time,ftop(i,1)
!设置当前载荷步终点时间
nsubst,10,0,0
!设置当前载荷步中的子步数目
fk,2,fx,ftop(i,2)
!施加当前载荷步的终点载荷
solve
*enddo
finish
/post26
ntop=node(0,0,10)
!利用node（x，y，z）提取顶点位置上的节点编号
nsol,2,ntop,u,x,ux_top
!定义顶点位置节点的位移UX(T)记录变量2
xvar,1
!时间记录变量1作为X轴映射变量
plvar,2
!绘制顶节点位移UX(T)记录变量2曲线
!创建二维数组utop（100，2）用时间序列及其对应位移填充它
*dim,utop,,100,2
!用时间序列填充数组utop（100，2）的第一列
*vfill,utop(1,1),ramp,0.1,0.1
!用位移响应ux序列填充数组utop（100，2）的第二列
vget,utop(1,2),2,0.1
!将二维数组utop（100，2）的数据写入文件utop.dat中
*cfopen,utop,dat,,
*do,i,1,100,1
*vwrite,utop(i,1),utop(i,2)
(f3.1,‘ ‘,f15.12)
!按格式将当前行数据写入utop.dat中
*enddo
*cfclose
*end