阴阳师第七章:用AS制作艺术时钟

1
用AS制作艺术时钟
教学目的：通过本节教学了解和掌握动作面板和as语句的添加、运用，进而制作出更加生动的动画，从而使你动画作品更具有感染力。
教学对象：本教材是针对有一定动画制作基础和对as语句有一定了解的朋友们编制的，因此省略了一些步骤，还望谅解。
制作步骤
1.启动FLASH8 软件。
2.确立文档属性 设置动画尺寸为200*220，帧频为12，背景颜色任意，其它默认,点击确定。如图1所示：

（图1）
3.在场景添加两个图层，共三个图层，自下而上分别命名为“背景”、“文本”和“as”。点击背景图层第一帧，导入一张你喜欢的图片，宽高为200*220，全居中，上锁。如图2所示：

（图2）
4.点击文本图层第一帧，选择文本工具在图片下方输入时钟名称，字体颜色自定。上锁。如图3所示：

（图3）
4.点击AS图层第一帧，打开动作面板输入下面语句：
//画钟表边线
this.createEmptyMovieClip("bianxian_mc", 1);
with (bianxian_mc) {
lineStyle(2, 0xCCCCCC);
moveTo(Math.cos(0*Math.PI/180)*96, Math.sin(0*Math.PI/180)*96);
for (var i =360; i>=0; i--) {
lineTo(Math.cos(i*Math.PI/180)*96, Math.sin(i*Math.PI/180)*96);
}
_x = 100;
_y = 110;
}
//创建时间动态文本
this.createTextField("my_txt", 2, 0, 0, 0, 0);
with (my_txt) {
autoSize = true;
textColor = 0x555555;
_x = 70;
_y = 60;
}
//画12个表格
this.createEmptyMovieClip("biaoge_mc", 3);
with (biaoge_mc) {
lineStyle(2, 0xCCCCCC);
moveTo(0, -96);
lineTo(0, -92);
_x = 100;
_y = 110;
}
for (i=1; i<12; i++) {
duplicateMovieClip(biaoge_mc, "biaoge_mc"+i, 3+i);
setProperty("biaoge_mc"+i, _rotation, i*30);
}
//画时针
this.createEmptyMovieClip("shizhen_mc", 16);
with (shizhen_mc) {
lineStyle(4, 0x666666);
moveTo(0, 0);
lineTo(0, -60);
_x = 100;
_y = 110;
}
//画分针
this.createEmptyMovieClip("fenzhen_mc", 17);
with (fenzhen_mc) {
lineStyle(2, 0x666666);
moveTo(0, 0);
lineTo(0, -75);
_x = 100;
_y = 110;
}
//画秒针
this.createEmptyMovieClip("miaozhen_mc", 18);
with (miaozhen_mc) {
lineStyle(1, 0x666666);
moveTo(0, 0);
lineTo(0, -90);
_x = 100;
_y = 110;
}
//让时针、分针、秒针动起来
this.createEmptyMovieClip("time_mc", 19);
time_mc.onEnterFrame = function() {
my_date = new Date();
shi = my_date.getHours();
fen = my_date.getMinutes();
miao = my_date.getSeconds();
shizhen_mc._rotation = shi/12*360+fen/60*30;
fenzhen_mc._rotation = fen/60*360+miao/60*6;
miaozhen_mc._rotation = miao/60*360;
if (shi<10) {
shi = "0"+shi;
}
if (fen<10) {
fen = "0"+fen;
}
if (miao<10) {
miao = "0"+miao;
}
my_txt.text = shi+"："+fen+"："+miao;
};
//画中心圆
this.createEmptyMovieClip("yuan_mc", 20);
with (yuan_mc) {
beginFill(0x555555);
moveTo(Math.cos(0*Math.PI/180)*4, Math.sin(0*Math.PI/180)*4);
for (var i =360; i>=0; i--) {
lineTo(Math.cos(i*Math.PI/180)*4, Math.sin(i*Math.PI/180)*4);
}
_x = 100;
_y = 110;
}
5.时间轴面板如图4所示：

图14
6.测试存盘
说明：你可以在最上层添加一个图层，为钟表加上漂亮的外壳：如果你想显示背景和钟表一样是圆形，那你可以在背景之上添加一个遮罩层或一个空心圆的边框。
最终效果显示：
',1)">
全屏下载
祝你成功！