中财网文圣天下txt网盘:oracle数据库备份脚本
来源：百度文库 编辑：中财网 时间：2024/05/11 01:48:01
@echo off
set 日期=%date:~0,10%
set dir=D:\OracleBackup
set fzbizfile=fbak
set fzbizfilename=%dir%\%fzbizfile%%日期%.dmp
set fzbizlogname=%dir%\%fzbizfile%%日期%.log
exp X3sys/sa@LZSJ file=%fzbizfilename% log=%fzbizlogname% compress=n buffer=4096000 consistent=y direct=n constraints=y feedback=10000 grants=y record=y indexes=y triggers=y rows=y
call :Date2Day %日期% days
set/a days=%days%-14
call :Day2Date %days% deldate
if exist %dir%\%fzbizfile%%deldate%.dmp (del %dir%\%fzbizfile%%deldate%.dmp)
if exist %dir%\%fzbizfile%%deldate%.log (del %dir%\%fzbizfile%%deldate%.log)
goto :TheEND
:Date2Day
setlocal ENABLEEXTENSIONS
for /f "tokens=1-3 delims=/-, " %%a in ('echo/%1') do (
set yy=%%a & set mm=%%b & set dd=%%c
)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
endlocal&set %2=%j%&goto :EOF
:Day2Date
setlocal ENABLEEXTENSIONS
set /a i=%1,a=i+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
endlocal&set %2=%yy%-%mm%-%dd%&goto :EOF
:TheEND